Keyboard shortcuts

Press ← or → to navigate between chapters

Press S or / to search in the book

Press ? to show this help

Press Esc to hide this help

番茄缠论插件函数说明

通达信

这里我们先假设DLL绑定的是4号DLL。

1号函数

输出分型的端点信号

SW:=TDXDLL4(1,H,L,0);

得到的SW是由-1、1和0组成的序列，-1表示是分型低点，1表示分型高点，0表示没有分型。

2号函数

输出笔的端点信号

BI:=TDXDLL4(2,H,L,0);

得到的BI是由-1、-0.5、0、0.5和1组成的序列，-1表示是笔低点，1表示是笔高点，0表示不是笔端点，-0.5表示的是下跌笔初成立，0.5表示的是上涨笔初成立。

3号函数

输出段的端点信号

DUAN:=TDXDLL4(3,BI,H,L);

得到的DUAN是由-1、-0.5、0、0.5和1组成的序列，-1表示是段低点，1表示是段高点，0表示不是段端点，-0.5表示的是下跌段初成立，0.5表示的是上涨段初成立。

4号函数

输出走势的端点信号

TREND:=TDXDLL4(4,DUAN,H,L);

得到的TREND是由-1、-0.5、0，0.5和1组成的序列，-1表示是走势的低点，1表示是走势的高点，0表示不是走势端点，-0.5表示的是下跌走势初成立，0.5表示的是上涨走势初成立。

5号函数

输出笔中枢的中枢高的价格序列数据

BIZG:=TDXDLL4(5,BI,H,L);

得到得BIZG是价格的序列，在中枢范围外的值是0，在中枢范围内的值是中枢高的价格。

6号函数

输出笔中枢高高数据

BIZGG:=TDXDLL4(6,BI,H,L);

得到的BIZGG是价格的序列，在中枢范围外的值是0，在中枢范围内的值是中枢高高的价格。

7号函数

输出笔中枢低数据

BIZD:=TDXDLL4(7,BI,H,L);

得到的BIZD是价格的序列，在中枢范围外的值是0，在中枢范围内的值是中枢低的价格。

8号函数

输出笔中枢低低数据

BIZDD:=TDXDLL4(8,BI,H,L);

得到的BIZDD是价格的序列，在中枢范围外的值是0，在中枢范围内的值是中枢低低的价格。

9号函数

输出笔中枢的起点和终点

BISE:=TDXDLL4(9,BI,H,L);

得到的BISE是笔中枢开始和结束的信号序列，1表示是笔中枢开始，2表示是笔中枢结束，其他都是0。

10号函数

输出中枢的方向

ZSD:=TDXDLL4(10,BI,H,L);

得到的ZSD是笔中枢方向的序列，在下跌中枢的区间里，他的输出值是-1，在上涨中枢的区间里，他的输出值是1，其他是0。

11号函数

输出是第几个中枢

ZSC:=TDXDLL4(10,BI,H,L);

得到的ZSC是第几个中枢的序列，在中枢的区间里，他的输出值当前是所在段中的第几个笔总数的数值。

12函数

重置参数，就是归0重置初始化，一般写在公式最开始的地方。

RESET:=TDXDLL4(12,0,0,0);

13号函数

传入参数到公式内，这个参数用来把配置选项传入到公式内，比如笔控制参数，段控制参数，中枢控制参数等。

SETOPT0:=TDXDLL4(13,0,WAVEOPT,0);
SETOPT3:=TDXDLL4(13,3,PIVOTOPT,0);

14号函数

没有用

15号函数

输出段中枢的中枢高的价格序列。

DUANZG:=TDXDLL4(15,DUAN,H,L);

得到的DUANZG是段中枢高的价格序列，在中枢区间里，他输出是中枢高的价格，其他地方输出的0。

16号函数

输出段中枢的中枢高高的价格序列。

DUANGG:=TDXDLL4(16,DUAN,H,L);

得到的DUANGG是段中枢高高的价格序列，在中枢区间里，他输出中枢高高的价格，其他地方他输出的是0。

17号函数

输出段中枢的中枢低价格序列

DUANZD:=TDXDLL4(17,DUAN,H,L);

得到的DUANZD是段中枢低的价格序列，在段中枢区间范围内，他的输出值是段中枢低的价格，其他地方他输出是0。

18号函数

输出段中枢的中枢低低的价格序列

DUANDD:=TDXDLL4(18,DUAN,H,L);

19号函数

输出段中枢起点和终点的信号序列。

DUANSE:=TDXDLL4(19,DUAN,H,L);

得到的DUANSE的序列值中，1表示是段中枢的起点，2表示是段中枢的结束点。

20号函数

经过包含处理后，当前K的方向是什么，-1表示是向下K，1表示是向上K。

KD:=TDXDLL4(10,H,L,0);

综合运用

把上面的函数组合起来，完成一个基本的缠论看盘公式就是如下：

RESET:=TDXDLL4(12,0,0,0);
SETOPT0:=TDXDLL4(13,0,WAVEOPT,0);
SETOPT3:=TDXDLL4(13,3,PIVOTOPT,0);

SW:=TDXDLL4(1,H,L,0);
NOTEXT_SWU:DRAWLINE(SW=-1,L,SW=+1,H,0), DOTLINE, COLORWHITE;
NOTEXT_SWD:DRAWLINE(SW=+1,H,SW=-1,L,0), DOTLINE, COLORWHITE;
SWZG:=TDXDLL4(5,SW,H,L);
SWZD:=TDXDLL4(7,SW,H,L);
SWSE:=TDXDLL4(9,SW,H,L);
NOTEXT_SWZG:IF(SWZG,SWZG,DRAWNULL),DOTLINE,COLORWHITE;
NOTEXT_SWZD:IF(SWZD,SWZD,DRAWNULL),DOTLINE,COLORWHITE;
NOTEXT_SWSE:STICKLINE(SWSE,SWZD,SWZG,0,-1),COLORWHITE;

BI:=TDXDLL4(2,H,L,0);
NOTEXT_BIU:DRAWLINE(BI=-1,L,BI=+1,H,0), COLORYELLOW;
NOTEXT_BID:DRAWLINE(BI=+1,H,BI=-1,L,0), COLORYELLOW;
BIZG:=TDXDLL4(5,BI,H,L);
BIZD:=TDXDLL4(7,BI,H,L);
BISE:=TDXDLL4(9,BI,H,L);
NOTEXT_BIZG:IF(BIZG,BIZG,DRAWNULL),COLORYELLOW;
NOTEXT_BIZD:IF(BIZD,BIZD,DRAWNULL),COLORYELLOW;
NOTEXT_BISE:STICKLINE(BISE,BIZD,BIZG,0,0),COLORYELLOW;

DUAN:=TDXDLL4(3,BI,H,L);
NOTEXT_DUANU:DRAWLINE(DUAN=-1,L,DUAN=+1,H,0), COLORFF8000;
NOTEXT_DUAND:DRAWLINE(DUAN=+1,H,DUAN=-1,L,0), COLORFF8000;
DUANZG:=TDXDLL4(15,DUAN,H,L);
DUANZD:=TDXDLL4(17,DUAN,H,L);
DUANSE:=TDXDLL4(19,DUAN,H,L);
NOTEXTDUANZG:IF(DUANZG,DUANZG,DRAWNULL),COLORFF8000;
NOTEXTDUANZD:IF(DUANZD,DUANZD,DRAWNULL),COLORFF8000;
NOTEXTDUANSE:STICKLINE(DUANSE,DUANZD,DUANZG,0,0),COLORFF8000;

TREND:=TDXDLL4(4,DUAN,H,L);
NOTEXT_TRENDU:DRAWLINE(TREND=-1,L,TREND=+1,H,0), COLORFFAEC9;
NOTEXT_TRENDD:DRAWLINE(TREND=+1,H,TREND=-1,L,0), COLORFFAEC9;
TRENDZG:=TDXDLL4(15,TREND,H,L);
TRENDZD:=TDXDLL4(17,TREND,H,L);
TRENDSE:=TDXDLL4(19,TREND,H,L);
NOTEXTTRENDZG:IF(TRENDZG,TRENDZG,DRAWNULL),COLORFFAEC9;
NOTEXTTRENDZD:IF(TRENDZD,TRENDZD,DRAWNULL),COLORFFAEC9;
NOTEXTTRENDSE:STICKLINE(TRENDSE,TRENDZD,TRENDZG,0,0),COLORFFAEC9;

MA5:MA(C,5);

画线说明：

  • 白色虚线：分型连线笔
  • 白色虚线框：分型中枢
  • 黄色线：笔
  • 黄色线框：笔中枢
  • 蓝色线：段
  • 蓝色线框：段中枢
  • 粉色线：走势

大智慧/金字塔/交易师

大智慧/金字塔/交易师的函数是一样的，所以我们合在一起写。

分型顶点

sw:="fqchan04@SW";

对标的是通达信的1号函数，输出分型顶点的信号。

笔顶点

bi:="fqchan04@BI"(WAVEOPT);

对标的是通达信的2号函数，输出笔顶点的信号。

段顶点

duan:="fqchan04@DUANVAR"(bi);

对标的是通达信的3号函数，输出段顶点的信号。

走势的顶点

trd:="fqchan04@TRENDVAR"(duan);

对标的是通达信的4号函数，输出走势顶点的信号。

中枢高

swzg:="fqchan04@ZSZGVAR"(sw,WAVEOPT,0,PIVOTOPT);
zszg:="fqchan04@ZSZGVAR"(bi,WAVEOPT,0,PIVOTOPT);
dzszg:="fqchan04@ZSZGVAR"(duan,WAVEOPT,0,PIVOTOPT);

对标通达信的5号函数，输出中枢高的价格序列，当然是在有中枢的地方，没有中枢的地方输出0。根据入参的不同，上面分别对应分型中枢高，笔中枢高和段中枢高。

中枢高高

swzg:="fqchan04@ZSGGVAR"(sw,WAVEOPT,0,PIVOTOPT);
zszg:="fqchan04@ZSGGVAR"(bi,WAVEOPT,0,PIVOTOPT);
dzszg:="fqchan04@ZSGGVAR"(duan,WAVEOPT,0,PIVOTOPT);

对标通达信的6号函数，在有中枢的地方输出中枢高高的价格序列。

中枢低

swzd:="fqchan04@ZSZDVAR"(sw,WAVEOPT,0,PIVOTOPT);
zszd:="fqchan04@ZSZDVAR"(bi,WAVEOPT,0,PIVOTOPT);
dzszd:="fqchan04@ZSZDVAR"(duan,WAVEOPT,0,PIVOTOPT);

对标通达信的7号函数，在有中枢的地方输出中枢低的价格序列。

中枢低低

swzd:="fqchan04@ZSDDVAR"(sw,WAVEOPT,0,PIVOTOPT);
zszd:="fqchan04@ZSDDVAR"(bi,WAVEOPT,0,PIVOTOPT);
dzszd:="fqchan04@ZSDDVAR"(duan,WAVEOPT,0,PIVOTOPT);

对标通达信的8号函数，在有中枢的地方输出中枢低低的价格序列。

中枢开始和结束

swse:="fqchan04@ZSSEVAR"(sw,WAVEOPT,0,PIVOTOPT);
zsse:="fqchan04@ZSSEVAR"(bi,WAVEOPT,0,PIVOTOPT);
dzsse:="fqchan04@ZSSEVAR"(duan,WAVEOPT,0,PIVOTOPT);

根据输入参数的不同，分别表示分型中枢的开始和结束、笔中枢的开始和结束和段中枢的开始和结束。

中枢方向

swzgfx:="fqchan04@ZSFXVAR"(sw,WAVEOPT,0,PIVOTOPT);
bizsfx:="fqchan04@ZSFXVAR"(bi,WAVEOPT,0,PIVOTOPT);
dzsfx:="fqchan04@ZSFXVAR"(duan,WAVEOPT,0,PIVOTOPT);

根据输入参数的不同，在有中枢的地方输出中枢的方向，-1表示向下中枢，1表示向上中枢。

中枢个数

swzggs:="fqchan04@ZSGSVAR"(sw,WAVEOPT,0,PIVOTOPT);
bizsgs:="fqchan04@ZSGSVAR"(bi,WAVEOPT,0,PIVOTOPT);
dzsgs:="fqchan04@ZSGSVAR"(duan,WAVEOPT,0,PIVOTOPT);

根据输入参数的不同，在有中枢的地方输出现在是当前方向上的第几个中枢，比如如果是笔中枢，那就是指当前段中的第几个中枢。

综合运用

综合运用起来，一个完整的基本看盘公式如下：

sw:="fqchan04@SW";
drawline(sw=1,h,sw=-1,l,0),colorwhite,linedot;
drawline(sw=-1,l,sw=1,h,0),colorwhite,linedot;
swzg:="fqchan04@ZSZGVAR"(sw,WAVEOPT,0,PIVOTOPT);
swzd:="fqchan04@ZSZDVAR"(sw,WAVEOPT,0,PIVOTOPT);
swse:="fqchan04@ZSSEVAR"(sw,WAVEOPT,0,PIVOTOPT);
DRAWLINE(swse=1, swzg, swse=2, swzg, 0), colorwhite, linedot;
DRAWLINE(swse=1, swzd, swse=2, swzd, 0), colorwhite, linedot;
STICKLINE(swse=1, swzg, swzd, 1, 0), colorwhite, linedot;
STICKLINE(swse=2, swzg, swzd, 1, 0), colorwhite, linedot;

bi:="fqchan04@BI"(WAVEOPT);
drawline(bi=1,h,bi=-1,l,0),coloryellow,linethick1;
drawline(bi=-1,l,bi=1,h,0),coloryellow,linethick1;
zszg:="fqchan04@ZSZGVAR"(bi,WAVEOPT,0,PIVOTOPT);
zszd:="fqchan04@ZSZDVAR"(bi,WAVEOPT,0,PIVOTOPT);
zsse:="fqchan04@ZSSEVAR"(bi,WAVEOPT,0,PIVOTOPT);
DRAWLINE(zsse=1, zszg, zsse=2, zszg, 0), coloryellow, linethick1;
DRAWLINE(zsse=1, zszd, zsse=2, zszd, 0), coloryellow, linethick1;
STICKLINE(zsse=1, zszg, zszd, 1, 0), coloryellow, linethick1;
STICKLINE(zsse=2, zszg, zszd, 1, 0), coloryellow, linethick1;

duan:="fqchan04@DUANVAR"(bi);
drawline(duan=1,h,duan=-1,l,0),colorff8000,linethick1;
drawline(duan=-1,l,duan=1,h,0),colorff8000,linethick1;
dzszg:="fqchan04@ZSZGVAR"(duan,WAVEOPT,0,PIVOTOPT);
dzszd:="fqchan04@ZSZDVAR"(duan,WAVEOPT,0,PIVOTOPT);
dzsse:="fqchan04@ZSSEVAR"(duan,WAVEOPT,0,PIVOTOPT);
DRAWLINE(dzsse=1, dzszg, dzsse=2, dzszg, 0), colorff8000, linethick1;
DRAWLINE(dzsse=1, dzszd, dzsse=2, dzszd, 0), colorff8000, linethick1;
STICKLINE(dzsse=1, dzszg, dzszd, 1, 0), colorff8000, linethick1;
STICKLINE(dzsse=2, dzszg, dzszd, 1, 0), colorff8000, linethick1;

trd:="fqchan04@TRENDVAR"(duan);
drawline(trd=1,h,trd=-1,l,0),colorffaec9,linethick1;
drawline(trd=-1,l,trd=1,h,0),colorffaec9,linethick1;
trdzszg:="fqchan04@ZSZGVAR"(trd,WAVEOPT,0,PIVOTOPT);
trdzszd:="fqchan04@ZSZDVAR"(trd,WAVEOPT,0,PIVOTOPT);
trdzsse:="fqchan04@ZSSEVAR"(trd,WAVEOPT,0,PIVOTOPT);
DRAWLINE(trdzsse=1, trdzszg, trdzsse=2, trdzszg, 0), colorffaec9, linethick1;
DRAWLINE(trdzsse=1, trdzszd, trdzsse=2, trdzszd, 0), colorffaec9, linethick1;
STICKLINE(trdzsse=1, trdzszg, trdzszd, 1, 0), colorffaec9, linethick1;
STICKLINE(trdzsse=2, trdzszg, trdzszd, 1, 0), colorffaec9, linethick1;